.DATE
.Run Name: CALC                    By: Rob Haeuser ©1994-2012 Ver. 11.000
*Function: Calculator runs stand-alone, @LNKed, or @CALLed as a subroutine.
*          The Total and Ticker are returned to the CALLing or LNKing run.
*===============================================================================
:L1=13,3=30,5=102,7=104,10=121,15=126,18=129,20=130,25=135,28=141,30=146,31=147
:L32=148,33=149,34=150,35=151,36=152,37=153,38=154,39=155,40=156,41=157,45=163
:L46=164,47=165,48=166,50=171,55=180,56=185,58=186,60=187,62=188,64=189,66=190
:L68=191,70=192,72=193,74=194,76=195,78=196,80=197,82=198,84=199,86=200,88=201
:L90=202,92=203,94=204,96=205,98=206,100=213,103=216,105=217,108=220,110=222
:L115=229,120=233,125=240,130=250,151=258,152=259,153=260,154=261,155=262
:L156=263,160=264,185=269,188=275,198=411,199=417
@0001:(<GT>) RAR 0199 RER,EDRW$,2 1 .
@     IF DLINE$ > 0 IF DRW$ > 0 RNM -1 CHG <DL>i6 DLINE$ ;.
@     IF WS$ > 0 . ;GTO 0198 .                  <- can only run on a Workstation
@     LDV <A1>h13='000000/cdcdcd',<A2>h13='000000/00ccee',\
          <A3>h13='ffffff/1111bb',<A4>h13='ffffff/777777',\
          <CC>i2,<FTF>h1,<HSZ>i3,<I>a15,<L>i4=6,<L2>i4,<LLN>i4=94,<LO>h1=+,\
          <M>s80,<MF>h1,<MPT>s40='Memory is currently empty',<MT>a15,<N1>i13,\
          <N2>i13,<O>h1=+,<SV>i1,<TH>a15,<TT>a15,<X>a15 .
@     IF RUN$ = CALC CHG INPUT$ <GT>a15 . ;LDV <X>=<GT>,<GT>a15=<X>,<X>='' .
@     IF <GT> = '' LDV <GT>=0 ;LDV,r <GT>,<I>=<GT> .
@     BRK SCN ,,,,,<HSZ> CHG <HSZ> <HSZ> /2 INC,2 <HSZ> .
.                            CALC Ticker
*
* Current Total        Operand          New Total       In Memory
*===============.=.===============.=.===============.===============.
@     IF <GT> = 0 LDV <L>=5 GTO 0003 ;LDV <L>=6 .
	<GT>                      <GT>
@0003:BRK RNM -2 LN+,-2,<L>,88 .
@     FON,t,'Courier New',22,bdp .
@     WIN,,5,<HSZ>,17,31,<A1>,ho ' GURU Calculator' <W>i6 .
@     MNU,,<W> MENUBAR,"&Quit",,L:0199
               MENUBAR,"&Ticker",,L:0130
               MENUBAR,"G&uru",,L:0185
               MENUBAR,"&Help",,L:0188
@     TXT,"",<W>,2,4,1,1,<A4>,3b <MH>i6 TIP," <MPT>(p) ",<MH> .   <- memory flag
@     EDT,"",<W>,2,9,1,15,<A2>,3r <EB>i6 .                         <- input area
@     TXT,"",<W>,2,28,1,1,<A3>,3b <OH>i6 .                          <- operation
@     BTN,<W>,4,3,2,4 'C' <C>i6 .
@     TIP," Clear the totals (this does NOT clear Memory) ",<C> .
@     BTN,<W>,4,9,2,5 '7' <7>i6 BTN,<W>,4,14,2,5 '8' <8>i6 .
@     BTN,<W>,4,19,2,5 '9' <9>i6 BTN,<W>,4,26,2,4 '+' <A>i6 .
@     BTN,<W>,6,3,2,4 'CE' <CE>i6 .
@     TIP," Clear the current entry only ",<CE> .
@     BTN,<W>,6,9,2,5 '4' <4>i6 BTN,<W>,6,14,2,5 '5' <5>i6 .
@     BTN,<W>,6,19,2,5 '6' <6>i6 BTN,<W>,6,26,2,4 '-' <S>i6 .
@     BTN,<W>,8,3,2,4 'MC' <MC>i6 .
@     TIP," Clear Memory ",<MC> .
@     BTN,<W>,8,9,2,5 '1' <1>i6 BTN,<W>,8,14,2,5 '2' <2>i6 .
@     BTN,<W>,8,19,2,5 '3' <3>i6 BTN,<W>,8,26,2,4 '*' <MU>i6 .
@     BTN,<W>,10,3,2,4 'MR' <MR>i6 .
@     TIP," Recall the value in Memory ",<MR> .
@     BTN,<W>,10,9,2,5 '0' <0>i6 BTN,<W>,10,14,2,5 '.' <P>i6 .
@     BTN,<W>,10,19,2,5 '=' <E>i6 BTN,<W>,10,26,2,4 '/' <D>i6 .
@     BTN,<W>,12,3,2,4 'M+' <MA>i6 .
@     TIP," Add the current total to Memory ",<MA> .
@     BTN,<W>,13,9,1,3 'Ab' <AB>i6 .
@     TIP," Absolute value or Magnitude ",<AB> .
@     BTN,<W>,13,12,1,3 'Ac' <AC>i6 .
@     TIP," Arc Cosine in Radians ",<AC> .
@     BTN,<W>,13,15,1,3 'As' <AS>i6 .
@     TIP," Arc Sine in Radians ",<AS> .
@     BTN,<W>,13,18,1,3 'At' <AT>i6 .
@     TIP," Arc Tangent in Radians ",<AT> .
@     BTN,<W>,13,21,1,3 'Cr' <CR>i6 .
@     TIP," Cube Root ",<CR> .
@     BTN,<W>,13,24,1,3 'Cs' <CS>i6 .
@     TIP," Cosine in Radians ",<CS> .
@     BTN,<W>,13,27,1,3 'Ct' <CT>i6 .
@     TIP," Co-Tangent in Radians ",<CT> .
@     BTN,<W>,14,3,2,4 'M-' <MS>i6 .
@     TIP," Subtract the current total from Memory",<MS> .
@     BTN,<W>,14,9,1,3 'Dr' <DR>i6 .
@     TIP," Radians expressed in Degrees ",<DR> .
@     BTN,<W>,14,12,1,3 'Ex' <EX>i6 .
@     TIP," Natural Number E raised to the Power of X ",<EX> .
@     BTN,<W>,14,15,1,3 'Fp' <FP>i6 .
@     TIP," Fractional Portion of X ",<FP> .
@     BTN,<W>,14,18,1,3 'Hc' <HC>i6 .
@     TIP," Hyperbolic Cosine of X ",<HC> .
@     BTN,<W>,14,21,1,3 'Hs' <HS>i6 .
@     TIP," Hyperbolic Sine of X ",<HS> .
@     BTN,<W>,14,24,1,3 'Ht' <HT>i6 .
@     TIP," Hyperbolic Tangent of X ",<HT> .
@     BTN,<W>,14,27,1,3 'Ip' <IP>i6 .
@     TIP," Interger Portion of X ",<IP> .
@     BTN,<W>,15,9,1,3 'Le' <LE>i6 .
@     TIP," Logarithm of X in Base E ",<LE> .
@     BTN,<W>,15,12,1,3 'Lt' <LT>i6 .
@     TIP," Logarithm of X in Base 10 ",<LT> .
@     BTN,<W>,15,15,1,3 'Pi' <PI>i6 .
@     TIP," Would you like a piece of apple PI? ",<PI> .
@     BTN,<W>,15,18,1,3 'Rd' <RD>i6 .
@     TIP," X Degrees in Radians ",<RD> .
@     BTN,<W>,15,21,1,3 'Si' <SI>i6 .
@     TIP," Sine of X Radians ",<SI> .
@     BTN,<W>,15,24,1,3 'Sr' <SR>i6 .
@     TIP," Square Root of X ",<SR> .
@     BTN,<W>,15,27,1,3 'Ta' <TA>i6 .
@     TIP," Tangent of X Radians ",<TA> FON,t .
@0005:TXT,"<O>",<OH> IF <I> > 0 JUV,r <I> ;.
@     CLS,<EB> EDT,"<I>(p)",<W>,2,9,1,15,<A2>,3r <EB> SHW,<W> .
@0007:INP,<EB>,,<W> <EB>,(0010),<OH>,(0020),<0>,(0030),<1>,(0031),<2>,(0032),\
                    <3>,(0033),<4>,(0034),<5>,(0035),<6>,(0036),<7>,(0037),\
                    <8>,(0038),<9>,(0039),<P>,(0040),<A>,(0045),<S>,(0046),\
                    <MU>,(0047),<D>,(0048),<E>,(0025),<C>,(0050),<CE>,(0055),\
                    <AB>,(0056),<AC>,(0058),<AS>,(0060),<AT>,(0062),\
                    <CR>,(0064),<CS>,(0066),<CT>,(0068),<DR>,(0070),\
                    <EX>,(0072),<FP>,(0074),<HC>,(0076),<HS>,(0078),\
                    <HT>,(0080),<IP>,(0082),<LE>,(0084),<LT>,(0086),\
                    <PI>,(0088),<RD>,(0090),<SI>,(0092),<SR>,(0094),\
                    <TA>,(0096),<MC>,(0100),<MH>,(0103),<MR>,(0103),\
                    <MA>,(0105),<MS>,(0108) ;.
@     IF INPUT$(1-2) = L: IF INPUT$(3-4) ge 1 & le MAXLAB$ GTO INPUT$(3-4) ;.
@     GTO 0151 .
@.
@. -----------------------------------------------------------------------------
@.                    Get the Input and Decide What To Do
@. -----------------------------------------------------------------------------
@0010:CHG INPUT$ <I> LCV '' <I> ','/'' DEF,x <SV>,<I> .           <- kill commas
@     IF <SV> = 1,9,(0018),2,4,6,(LIN1),5,(0015) ;GTO 0151 .     <- valid input?
@     LDV,l <I> IF <I> = +,-,*,/ LDV <O>=<I> GTO 0028 ;. <- entered an operator?
@     IF <I> = C,(0050),CE,(0055),MC,(0100),MR,(0103),M+,(0105),M-,(0108) ;.
@     GTO 0151 .
@0015:LDV,r <I> IF <I>(15-1) = +,-,*,/ LDV <O>=<I>(15-1),<I>(15-1)='' GTO 0020 .
@     LDV,l <I> IF <I>(1-1) = +,-,*,/ LDV <LO>=<I>(1-1),<I>(1-1)='' GTO 0020 ;.
@     GTO 0115 .                                <- we have an inline calculation
@0018:LDV,l <I> IF <I>(1-1) = +,-,*,/ LDV <LO>=<I>(1-1),<I>(1-1)='' ;.
@0020:LDV,r <I>,<TH>=<I> .
@.
@. -----------------------------------------------------------------------------
@.                   Calculate it and Display the new Total
@. -----------------------------------------------------------------------------
@0025:IF <LO> ne '/' . ;IF <TH> ne 0 . ;GTO 0156 .      <- can't divide by zero!
@     IF <TH> ne '' . ;LDV <TH>=0 .                         <- it can't be blank
@     LDV <X>=<GT> ART <GT><LO><TH> <GT> .                            <- calc it
@     IF <FTF> = X . ;LDV <FTF>=X GTO 0028 .
@     LDV,r <TH> INC <L> IF <L> le <LLN> . ;LN+,-2,<LLN>,88 .
@     WRL,-2,<L>,y 2-15,18-1,20-15,36-1,38-15,54-15 	,<X>,<LO>,<TH>,=,<GT>,<MT>
@0028:LDV <I>=<GT>,<LO>=<O>,<TH>='' GTO 0005 .                 <- show new total
@.
@. -----------------------------------------------------------------------------
@.                    They clicked a Number or the Period
@. -----------------------------------------------------------------------------
@0030:LDV <I>=0 GTO 0041 .                                         <- "0" button
@0031:LDV <I>=1 GTO 0041 .                                         <- "1" button
@0032:LDV <I>=2 GTO 0041 .                                         <- "2" button
@0033:LDV <I>=3 GTO 0041 .                                         <- "3" button
@0034:LDV <I>=4 GTO 0041 .                                         <- "4" button
@0035:LDV <I>=5 GTO 0041 .                                         <- "5" button
@0036:LDV <I>=6 GTO 0041 .                                         <- "6" button
@0037:LDV <I>=7 GTO 0041 .                                         <- "7" button
@0038:LDV <I>=8 GTO 0041 .                                         <- "8" button
@0039:LDV <I>=9 GTO 0041 .                                         <- "9" button
@0040:LDV <I>='.' .                                                <- "." button
@0041:LDV,l <TH> LDV <TH>(0-1)=<I> LCV T@ <TH> ' '/'' LDV,r <TH>,<I>=<TH> .
@     GTO 0005 .                                             <- accumulate input
@.
@. -----------------------------------------------------------------------------
@.                          They clicked an Operator
@. -----------------------------------------------------------------------------
@0045:LDV <O>=+ GTO 0025 .                                         <- "+" button
@0046:LDV <O>=- GTO 0025 .                                         <- "-" button
@0047:LDV <O>=* GTO 0025 .                                         <- "*" button
@0048:LDV <O>=/ GTO 0025 .                                         <- "/" button
@.
@. -----------------------------------------------------------------------------
@.                   They clicked Clear All or Clear Entry
@. -----------------------------------------------------------------------------
@0050:LDV,r <FTF>=,<GT>=0,<I>=0,<LO>=+,<O>=+,<TH>='' .              <- clear all
@     IF <L> > 5 . ;GTO 0005 .                                   <- restart tckr
@     LN+,-2,<L>,3 INC <L> WRL,-2,<L>,y 2-68\
      *,******************************************************************** .
@     INC <L> WRL,-2,<L>,y 2-68\
      *,'*************** Current calculations have been cleared *************' .
@     INC <L> WRL,-2,<L>,y 2-68\
      *,******************************************************************** .
@     GTO 0005 .
@0055:LDV <I>=,<TH>='' GTO 0005 .                                 <- clear entry
@.
@. -----------------------------------------------------------------------------
@.                      Scientific Calculations Section
@. -----------------------------------------------------------------------------
@0056:LDV <F>h3=ABS GTO 0098 .                    <- absolute value or magnitude
@0058:IF <I> ge -1 & le 1 LDV <F>h4=ACOS GTO 0098 ;GTO 0152 .      <- arc cosine
@0060:IF <I> ge -1 & le 1 LDV <F>h4=ASIN GTO 0098 ;GTO 0152 .        <- arc sine
@0062:LDV <F>h4=ATAN GTO 0098 .                                   <- arc tangent
@0064:LDV <F>h4=CBRT GTO 0098 .                                     <- cube root
@0066:LDV <F>h3=COS  GTO 0098 .                                        <- cosine
@0068:LDV <F>h3=CTN  GTO 0098 .                                     <- cotangent
@0070:LDV <F>h3=DEG  GTO 0098 .                  <- radians expressed in degrees
@0072:IF <I> ge 0 & le 709 LDV <F>h3=EXP GTO 0098 ;GTO 0153 . <-exponent(E to n)
@0074:LDV <F>h4=FRAC GTO 0098 .                            <- fractional portion
@0076:IF <I> ge -710 & le 710 LDV <F>h4=HCOS GTO 0098 ;GTO 0154 .  <- hyprblc cs
@0078:IF <I> ge -710 & le 710 LDV <F>h4=HSIN GTO 0098 ;GTO 0154 .  <- hyprblc sn
@0080:LDV <F>h4=HTAN GTO 0098 .                            <- hyperbolic tangent
@0082:LDV <F>h3=INT GTO 0098 .                                <- integer portion
@0084:IF <I> > 0 LDV <F>h3=LOG GTO 0098 ;GTO 0155 .        <- logarith in base e
@0086:IF <I> > 0 LDV <F>h5=LOG10 GTO 0098 ;GTO 0155 .     <- logarith in base 10
@0088:ART PI <I> LDV <TH>=<I> GTO 0005 .                                   <- pi
@0090:LDV <F>h3=RAD GTO 0098 .                             <- degrees in radians
@0092:LDV <F>h3=SIN GTO 0098 .                                           <- sine
@0094:IF <I> > 0 LDV <F>h4=SQRT GTO 0098 ;GTO 0155 .              <- square root
@0096:LDV <F>h3=TAN .                                                 <- tangent
@0098:IF <I> ne ''  LDV,p <IX>a15=<I> . ;LDV <IX>i1=1 .
@     XQT '@ART '<F>'('<IX>') <I> ' .                  <- scientific calculation
@     GTO 0005 .
@.
@. -----------------------------------------------------------------------------
@.                             Memory Operations
@. -----------------------------------------------------------------------------
@0100:TXT," ",<MH> LDV <MT>='',<MF>=,<I>=<GT>  GTO 0005 .   <- clear memory flag
@     LDV <MPT>='Memory is currently empty' TIP," <MPT>(p) ",<MH>.
@     IF <L> > 5 WRL,-2,<L>,y 54-15 	,<MT> ;GTO 0005 .
@0103:LDV <I>=<MT>,<TH>=<MT> GTO 0005 .                         <- recall memory
@0105:IF <I> ne '' & ne M+ ART <MT>+<I> <MT> LDV <I>=<MT> . ;\       <- memory +
        IF <I> = M+ LDV <I>=<GT>,<MT>=<GT> ;.
@     GTO 0110 .
@0108:IF <I> ne '' & ne M- ART <MT>-<I> <MT> LDV <I>=<MT> . ;\       <- memory -
        IF <I> = M- LDV <I>=<GT>,<MT>=<GT> ;.
@0110:IF <MF> = '' TXT,"M",<MH> LDV <MF>=X ;.
@     LDV <MPT>='Current value in Memory = '<MT>(p) TIP," <MPT>(p) ",<MH> .
@     WRL,-2,<L>,y 54-15 	,<MT> GTO 0005 .

@. -----------------------------------------------------------------------------
@.                       Perform an in-line calculation
@. -----------------------------------------------------------------------------
@0115:LCV,LIN1 '' <I> '+' <CC> GTO 0120 .
@     LCV,LIN1 '' <I> '-' <CC> GTO 0120 .
@     LCV,LIN1 '' <I> '*' <CC> GTO 0120 .
@     LCV,0151 '' <I> '/' <CC> .
@0120:LDV <O>=<I>(<CC>-1) DEC <CC> .
@     LDV <N1>=<I>(1-<CC>) INC,2 <CC> LDV <N2>=<I>(<CC>-0),<TT>=<GT> .
@     ART <N1><O><N2>;<TT><LO>A <TH>,<TT> LDV <O>=<LO> .
@     IF <O> = + LDV <TX1>h3=add,<TX2>h2=to GTO 0125 ;.
@     IF <O> = - LDV <TX1>h8=subtract,<TX2>h4=from GTO 0125 ;.
@     IF <O> = * LDV <TX1>h8=multiply,<TX2>h2=by GTO 0125 ;.
@     LDV <TX1>h6=divide,<TX2>h4=into .
@0125:MBX,yn,i,'In-line Result'\
 'The result of your in-line calculation is  '<TH>(p)'            '//\
'Do you want to '<TX1>' it '<TX2>' the total?'//\
'     (The current total is '<GT>(p)','/\
'      and the new total will be '<TT>(p)')' Y,(0025),N,(LIN1) .
@     LDV <I>=<GT> GTO 0005 .
@.
@. -----------------------------------------------------------------------------
@.                           Show the CALC Ticker
@. -----------------------------------------------------------------------------
@0130:SRH,-2,6,,LIN1 @ADN 2-68 	,@ LLN,-0 <L2> LN+,-0,<L2>,1 .
@     HID,<W> LDV,c <M>='Press F1 to return to CALC' KEY DSP,-0,,,,,,<M> .
@     SHW,<W> IF DRW1$ > 0 DSP,-1,<DL>,,,y . ;SC q CS .
@     GTO 0007 .
@.
@. -----------------------------------------------------------------------------
@.                               Error Messages
@. -----------------------------------------------------------------------------
@0151:LDV <M>='I do not understand your input.  Please try again.' GTO 0160 .
@0152:LDV <M>='Valid range is -1 to +1' GTO 0160 .
@0153:LDV <M>='Valid range is 0 to 709' GTO 0160 .
@0154:LDV <M>='Valid range is -710 to 710' GTO 0160 .
@0155:LDV <M>='Number must be greater than 0' GTO 0160 .
@0156:LDV <M>='You cannot divide by zero' .
@0160:LDV <I>=<GT>,<TH>='' MBX,,s,'Input error' <M>(p)'          ' O,(0005) .
@.
@. -----------------------------------------------------------------------------
@.                                  Run GURU
@. -----------------------------------------------------------------------------
@0185:IF DRW1$ > 0 RNM,-1 -0 . ;BRK DLR,-0 .
@     CLK CLS RUN GURU .
@.
@. -----------------------------------------------------------------------------
@.                                    Help
@. -----------------------------------------------------------------------------
@0188:BRK .

    Enter numbers either via the keyboard or by clicking the
 number buttons. If you use the keyboard, transmit your input
 by pressing the Enter key, or it will be discarded. You can
 also enter the "alpha" commands via the keyboard: C (Clear),
 CE (Clear Entry), MR (Memory Recall), MC (Memory Clear), M+
 (Add to Memory), and M- (Subtract from Memory). Even though
 it is possible to enter via both the keyboard and mouse, I
 recommend that you stick with one method because of the
 subtle differences between the two.

    CALC starts in add mode, as indicated by a "+" in the
 current operator box to the right of the entry area. You can
 change mode of operation by clicking the "+", "-", "*", or
 "/" buttons, or via the other methods described below.

    When entering from the keyboard, you can change the
 operator for either the current entry only or for all
 subsequent entries (until the operator is changed again).
 For example, if in add mode and you transmit -15, then
 subtraction becomes the active operator for the current
 calculation only, and 15 will be subtracted from the total.
 However, the mode of operation remains addition.

 If you enter 15- then 15 is added to the total, and the mode
 of operation becomes subtraction for subsequent entries.

    Normally you enter one number at a time, but CALC also
 accepts simple "in-line" calculations. For example, suppose
 you added a series of numbers, and that the current total is
 88. If you then enter 4*17 CALC will display a popup message
 to inform you that the result of the in-line calculation is
 68, that the current total is 88, and that the result of
 adding 68 to 88 will be 156. CALC then asks if you want to
 proceed to add the in-line result to the current total. If
 you choose not to, the current total of 88 is re-displayed.
 Note: you cannot enter compound equations in-line, such as
 (12*45)+77.8. To perform this equation, you could enter 77.8
 (with the current operator being "+") and then enter 12*45.
 CALC will display the popup message, and if you accept the
 inline calculation, the new total of 617.8 will be displayed.
 Also note that the inline operator (in this example it is
 multiply) does not alter the current mode of operation (+),
 so entering subsequent numbers will continue to add them to
 the running total.

    Click M+ or M- to modify the value in memory. The current
 total will be added to or subtracted from memory, which is
 initially set to zero. If entering via the keyboard, transmit
 prior to clicking M+ or M- or your entry will be discarded.
 You can also type M+ or M- and transmit. When memory is
 activated an "M" will be displayed in the box to the left of
 the input area.

    To recall and display stored memory, click MR or the "M"
 in the "Memory Active" box to the left of the input area.
 The stored number will be displayed, but you must still
 process it by transmitting or clicking an operation button.

    If the total exceeds 15 digits, it will be displayed in
 scientific notation, where the letter E followed by a number
 (representing the power of 10) indicates which direction and
 how many positions to move the decimal point. For example,
 173E6 would represent 173,000,000. In this case, E6 is
 indicating that there are six zeroes to the right of the
 number 173. Another example is .12345E-3, which represents
 .00012345, where E-3 indicates three zeroes to the left.
 Please note that a number shown in scientific notation may
 be rounded. Also note that you cannot enter scientific
 notation as input.

    The 3 rows of buttons on the bottom are for scientific
 calculations, and are defined as follows:

       Ab = Absolute value       Ac = Arc cosine
       As = Arc sine             At = Arc tangent
       Cr = Cube root            Cc = cosine
       Ct = Cotangent            Dr = Degrees radian
       Ex = Exponentiate "e"     Fp = Fractional portion
       Hc = Hyperbolic cosine    Hs = Hyperbolic sine
       Ht = Hyperbolic tangent   Ip = Integer portion
       Le = Logarithm base "e"   Lt = Logarithm base 10
       Pi = Value of PI          Rd = Radian degrees
       Si = Sine                 Sr = Square root
       Ta = Tangent

    CALC keeps a running "ticker" of your calculations. You
 can display the ticker at any time by clicking Ticker on
 the menubar. When the ticker is displayed, you can print it
 if desired via Options on the menubar. Click Back to return
 to CALC. When you click Clear (all), the ticker running
 totals are reset, but your previous calculations will remain
 in the ticker for your viewing pleasure. Note: Scientific
 Calculations are not recorded in the ticker.

    Warning! Fuzzy Logic ahead...
 Transmitting is iterative. For example, if you''re in add
 mode amd the current total is 2, transmit and CALC will add
 2 to the current total, yielding a new total of 4. A second
 transmit adds 4 to itself, yielding 8. A 3rd transmit adds
 8 to 8, yielding 16, and so on. This is probably only useful
 in add mode. In a nutshell, if you transmit a second time
 while in add mode, the current total will be doubled. Good
 luck finding a real use for this, but enter a 2 and transmit
 repeatedly to see why your computer prefers certain numbers,
 and why in computer-speak 1K is actually 1,024.

    The following information is for Run Designers.

    CALC can be run stand-alone, @LNKed, or @CALLed. When
 called, if you pass CALC a variable the Grand Total will be
 returned to the calling run.

    The syntax for a call is: @CALL,''GURU'',86 1*('<GT>')
 where ''GURU'' is the GURU drawer named during the GURU
 installation. Note: CALC initializes '<GT>' as '<GT>'a15.

    If linked, CALC loads the Grand Total in an environmental
 variable initialized as '<$GT>'a15. This variable will exist
 for the duration of the user''s session unless you perform a
 @CLV,e (note that this clears ALL environmental variables).

    Whether @LNKed or @CALLed, CALC returns a "Ticker" result
 that lists of all calculations performed. If you''re run
 creates a result that needs to be retained, be sure to rename
 it before accessing CALC.

@     BRK WIN,,4,14,23,69,<A1>,ho ' GURU Calculator Help' <HW>i6 .
@     MNU,,<HW> MENUBAR,"&Return",,'' .
@     LST,-0,2,y,CALC_Help,<HW>,2,3,20,65,<A3> '' HID,<W> SHW,<HW> INP,,,<HW> .
@     CLS,<HW> GTO 0005 .
@.
@. -----------------------------------------------------------------------------
@.                                Fatal Error
@. -----------------------------------------------------------------------------
@0198:SC q ATT;EEL;FLD,1,1,,SCNH$,c,(WHI/RED),,\
TIC$'<< Sorry, but CALC can only be run on a GUI Workstation >>'TIC$ WAT 4000 .
@.
@. -----------------------------------------------------------------------------
@.                                    QED
@. -----------------------------------------------------------------------------
@0199:CLS,<W> IF RUN$ = CALC . ;RETURN .
@     IF LINK$ = 0 LZR,-1,LIN1 DSX,-1,<DL> . ;LDV <$GT>a15=<GT> GTO END .
@     REL .
................................ Variable Table ................................
.<A1> - <A3> = Screen Colors
.<0> - <9>     = Handles: 0 thru 9
.<A>           = Handle: Add (+)
.<C>           = Handle: Clear (C)
.<CC>          = Column Counter
.<CE>          = Handle: Clear Entry (CE)
.<D>           = Handle: Divide (/)
.<DL>          = Displayed Line #
.<E>           = Handle: Equals (=)
.<EB>          = Handle: Edit Box
.<F>           = Function
.<FTF>         = First-Time Flag - used to skip the first write to -2
.<GT>          = Grand Total
.<HSZ>         = Horizontal Size of the screen
.<HW>          = Handle: Help Window
.<I>           = Input
.<IX>          = Packed version of <I>
.<L>           = Line #
.<L2>          = Line # in -0 result from ticker
.<LLN>         = Last Line # in -2 .
.<LO>          = Last Operation
.<M>           = Messages
.<MA>          = Handle: Memory Add
.<MF>          = Memory Flag (equals X if memory is active)
.<MH>          = Handle: Memory Flag
.<MS>          = Handle: Memory Subtract
.<MT>          = Memory Total
.<MPT>         = Memory Popup Text
.<MU>          = Handle: Multiply (*)
.<N1>          = 1st Number in a compound entry (if A+B is entered, <N1> = A)
.<N2>          = 2nd Number in a compound entry (if A+B is entered, <N2> = B)
.<O>           = Current Operation (+, -, *, /)
.<OH>          = Handle: Current Operation
.<P>           = Handle: Period (.)
.<S>           = Handle: Subtract (-)
.<TH>          = Temporary Holder
.<TT>          = Temporary Total
.<W>           = Handle: Window
.
.  All variables initialized for the scientific function buttons represent
.  their associated handles.